(global-set-key (kbd "C-c e c") 'ce-chars-at-point)
(global-set-key (kbd "C-c e l") 'ce/cp)

;; commands for dictionary lookups
;;
(defvar jjf-ce-dict "/home/sketch/lib/cedict_1_0_ts_utf-8_mdbg.txt"
  "Filename of utf8 chinese-english dictionary.")

(define-grep-command ce jjf-ce-dict)

(defun ce-chars-at-point (exact nchars)
  "Look up NCHARS characters after point with the `ce' grepper,
ignoring whitespace between characters.  With prefix-arg EXACT,
put word boundaries around the string passed to grep."
  (interactive
   (list current-prefix-arg
         (string-to-number
          (char-to-string
           (read-char "nchars?")))))
  (when (looking-at
         (mapconcat 'identity
                    (make-list nchars "\\(\\w\\)")
                    "\\s-*"))
    (let ((wd (apply 'concat
                     (let (result)
                       (dotimes (i nchars (nreverse result))
                         (setq result
                               (cons (match-string-no-properties (1+ i))
                                     result)))))))
      (if exact
          (ce (concat "\\b" wd "\\b"))
          (ce wd)))))

(defun ce/cp (exact s)
  "This command is for looking up words in a chinese-english
dictionary file by chinese pinyin pronunciation without having to
write the tone numbers.  The regexp `[1-5]\\?' will be appended
to each syllable in the word you give.  Separate syllables by
whitespace.

When a prefix arg EXACT is given, only entries with /exactly/ the
given syllables will be matched, as opposed to entries merely
/containing/ the syllables."
  (interactive "P\nsString? ")
  (ce
   (concat
    (if exact "\\[" "")
    (mapconcat
     (lambda (x)
       (concat x "[1-5]\\?"))
     (split-string s nil t)
     " ")
    (if exact "\\]" ""))))